maintenance/postgres/compare_schemas.pl

   1 #!/usr/bin/perl
   2
   3 ## Rough check that the base and postgres "tables.sql" are in sync
   4 ## Should be run from maintenance/postgres
   5 ## Checks a few other things as well...
   6
   7 use strict;
   8 use warnings;
   9 use Data::Dumper;
  10 use Cwd;
  11
  12 #check_valid_sql();
  13
  14 my @old = ('../tables.sql');
  15 my $new = 'tables.sql';
  16 my @xfile;
  17
  18 ## Read in exceptions and other metadata
  19 my %ok;
  20 while (<DATA>) {
  21         next unless /^(\w+)\s*:\s*([^#]+)/;
  22         my ($name,$val) = ($1,$2);
  23         chomp $val;
  24         if ($name eq 'RENAME') {
  25                 die "Invalid rename\n" unless $val =~ /(\w+)\s+(\w+)/;
  26                 $ok{OLD}{$1} = $2;
  27                 $ok{NEW}{$2} = $1;
  28                 next;
  29         }
  30         if ($name eq 'XFILE') {
  31                 push @xfile, $val;
  32                 next;
  33         }
  34         for (split /\s+/ => $val) {
  35                 $ok{$name}{$_} = 0;
  36         }
  37 }
  38
  39 my $datatype = join '|' => qw(
  40 bool
  41 tinyint int bigint real float
  42 tinytext mediumtext text char varchar varbinary binary
  43 timestamp datetime
  44 tinyblob mediumblob blob
  45 );
  46 $datatype .= q{|ENUM\([\"\w, ]+\)};
  47 $datatype = qr{($datatype)};
  48
  49 my $typeval = qr{(\(\d+\))?};
  50
  51 my $typeval2 = qr{ signed| unsigned| binary| NOT NULL| NULL| PRIMARY KEY| AUTO_INCREMENT| default ['\-\d\w"]+| REFERENCES .+CASCADE};
  52
  53 my $indextype = join '|' => qw(INDEX KEY FULLTEXT), 'PRIMARY KEY', 'UNIQUE INDEX', 'UNIQUE KEY';
  54 $indextype = qr{$indextype};
  55
  56 my $engine = qr{TYPE|ENGINE};
  57
  58 my $tabletype = qr{InnoDB|MyISAM|HEAP|HEAP MAX_ROWS=\d+|InnoDB MAX_ROWS=\d+ AVG_ROW_LENGTH=\d+};
  59
  60 my $charset = qr{utf8|binary};
  61
  62 open my $newfh, '<', $new or die qq{Could not open $new: $!\n};
  63
  64
  65 my ($table,%old);
  66
  67 ## Read in the xfiles
  68 my %xinfo;
  69 for my $xfile (@xfile) {
  70         print "Loading $xfile\n";
  71         my $info = parse_sql($xfile);
  72         for (keys %$info) {
  73                 $xinfo{$_} = $info->{$_};
  74         }
  75 }
  76
  77 for my $oldfile (@old) {
  78         print "Loading $oldfile\n";
  79         my $info = parse_sql($oldfile);
  80         for (keys %xinfo) {
  81                 $info->{$_} = $xinfo{$_};
  82         }
  83         $old{$oldfile} = $info;
  84 }
  85
  86 sub parse_sql {
  87
  88         my $oldfile = shift;
  89
  90         open my $oldfh, '<', $oldfile or die qq{Could not open $oldfile: $!\n};
  91
  92         my %info;
  93         while (<$oldfh>) {
  94                 next if /^\s*\-\-/ or /^\s+$/;
  95                 s/\s*\-\- [\w ]+$//;
  96                 chomp;
  97
  98                 if (/CREATE\s*TABLE/i) {
  99                         if (m{^CREATE TABLE /\*_\*/(\w+) \($}) {
 100                                 $table = $1;
 101                         }
 102                         elsif (m{^CREATE TABLE /\*\$wgDBprefix\*/(\w+) \($}) {
 103                                 $table = $1;
 104                         }
 105                         else {
 106                                 die qq{Invalid CREATE TABLE at line $. of $oldfile\n};
 107                         }
 108                         $info{$table}{name}=$table;
 109                 }
 110                 elsif (m{^\) /\*\$wgDBTableOptions\*/}) {
 111                         $info{$table}{engine} = 'ENGINE';
 112                         $info{$table}{type} = 'variable';
 113                 }
 114                 elsif (/^\) ($engine)=($tabletype);$/) {
 115                         $info{$table}{engine}=$1;
 116                         $info{$table}{type}=$2;
 117                 }
 118                 elsif (/^\) ($engine)=($tabletype), DEFAULT CHARSET=($charset);$/) {
 119                         $info{$table}{engine}=$1;
 120                         $info{$table}{type}=$2;
 121                         $info{$table}{charset}=$3;
 122                 }
 123                 elsif (/^  (\w+) $datatype$typeval$typeval2{0,4},?$/) {
 124                         $info{$table}{column}{$1} = $2;
 125                         my $extra = $3 || '';
 126                         $info{$table}{columnfull}{$1} = "$2$extra";
 127                 }
 128                 elsif (m{^  UNIQUE KEY (\w+) \((.+?)\)}) {
 129                 }
 130                 elsif (m{^CREATE (?:UNIQUE )?(?:FULLTEXT )?INDEX /\*i\*/(\w+) ON /\*_\*/(\w+) \((.+?)\);}) {
 131                 }
 132                 elsif (m{^\s*PRIMARY KEY \([\w,]+\)}) {
 133                 }
 134                 else {
 135                         die "Cannot parse line $. of $oldfile:\n$_\n";
 136                 }
 137
 138         }
 139         close $oldfh or die qq{Could not close "$oldfile": $!\n};
 140
 141         return \%info;
 142
 143 } ## end of parse_sql
 144
 145 ## Read in the parser test information
 146 my $parsefile = '../parserTests.inc';
 147 open my $pfh, '<', $parsefile or die qq{Could not open "$parsefile": $!\n};
 148 my $stat = 0;
 149 my %ptable;
 150 while (<$pfh>) {
 151         if (!$stat) {
 152                 if (/function listTables/) {
 153                         $stat = 1;
 154                 }
 155                 next;
 156         }
 157         $ptable{$1}=2 while m{'(\w+)'}g;
 158         last if /\);/;
 159 }
 160 close $pfh or die qq{Could not close "$parsefile": $!\n};
 161
 162 my $OK_NOT_IN_PTABLE = '
 163 change_tag
 164 filearchive
 165 logging
 166 profiling
 167 querycache_info
 168 searchindex
 169 tag_summary
 170 trackbacks
 171 transcache
 172 user_newtalk
 173 updatelog
 174 valid_tag
 175 ';
 176
 177 ## Make sure all tables in main tables.sql are accounted for in the parsertest.
 178 for my $table (sort keys %{$old{'../tables.sql'}}) {
 179         $ptable{$table}++;
 180         next if $ptable{$table} > 2;
 181         next if $OK_NOT_IN_PTABLE =~ /\b$table\b/;
 182         print qq{Table "$table" is in the schema, but not used inside of parserTest.inc\n};
 183 }
 184 ## Any that are used in ptables but no longer exist in the schema?
 185 for my $table (sort grep { $ptable{$_} == 2 } keys %ptable) {
 186         print qq{Table "$table" ($ptable{$table}) used in parserTest.inc, but not found in schema\n};
 187 }
 188
 189 for my $oldfile (@old) {
 190
 191 ## Begin non-standard indent
 192
 193 ## MySQL sanity checks
 194 for my $table (sort keys %{$old{$oldfile}}) {
 195         my $t = $old{$oldfile}{$table};
 196         if ($t->{engine} eq 'TYPE') {
 197                 die "Invalid engine for $oldfile: $t->{engine}\n" unless $t->{name} eq 'profiling';
 198         }
 199         my $charset = $t->{charset} || '';
 200         if ($oldfile !~ /binary/ and $charset eq 'binary') {
 201                 die "Invalid charset for $oldfile: $charset\n";
 202         }
 203 }
 204
 205 my $dtype = join '|' => qw(
 206 SMALLINT INTEGER BIGINT NUMERIC SERIAL
 207 TEXT CHAR VARCHAR
 208 BYTEA
 209 TIMESTAMPTZ
 210 CIDR
 211 );
 212 $dtype = qr{($dtype)};
 213 my %new;
 214 my ($infunction,$inview,$inrule,$lastcomma) = (0,0,0,0);
 215 seek $newfh, 0, 0;
 216 while (<$newfh>) {
 217         next if /^\s*\-\-/ or /^\s*$/;
 218         s/\s*\-\- [\w ']+$//;
 219         next if /^BEGIN;/ or /^SET / or /^COMMIT;/;
 220         next if /^CREATE SEQUENCE/;
 221         next if /^CREATE(?: UNIQUE)? INDEX/;
 222         next if /^CREATE FUNCTION/;
 223         next if /^CREATE TRIGGER/ or /^  FOR EACH ROW/;
 224         next if /^INSERT INTO/ or /^  VALUES \(/;
 225         next if /^ALTER TABLE/;
 226         chomp;
 227
 228         if (/^\$mw\$;?$/) {
 229                 $infunction = $infunction ? 0 : 1;
 230                 next;
 231         }
 232         next if $infunction;
 233
 234         next if /^CREATE VIEW/ and $inview = 1;
 235         if ($inview) {
 236                 /;$/ and $inview = 0;
 237                 next;
 238         }
 239
 240         next if /^CREATE RULE/ and $inrule = 1;
 241         if ($inrule) {
 242                 /;$/ and $inrule = 0;
 243                 next;
 244         }
 245
 246         if (/^CREATE TABLE "?(\w+)"? \($/) {
 247                 $table = $1;
 248                 $new{$table}{name}=$table;
 249                 $lastcomma = 1;
 250         }
 251         elsif (/^\);$/) {
 252                 if ($lastcomma) {
 253                         warn "Stray comma before line $.\n";
 254                 }
 255         }
 256         elsif (/^  (\w+) +$dtype.*?(,?)(?: --.*)?$/) {
 257                 $new{$table}{column}{$1} = $2;
 258                 if (!$lastcomma) {
 259                         print "Missing comma before line $. of $new\n";
 260                 }
 261                 $lastcomma = $3 ? 1 : 0;
 262         }
 263         elsif (m{^\s*PRIMARY KEY \([\w,]+\)}) {
 264                 $lastcomma = 0;
 265         }
 266         else {
 267                 die "Cannot parse line $. of $new:\n$_\n";
 268         }
 269 }
 270
 271 ## Which column types are okay to map from mysql to postgres?
 272 my $COLMAP = q{
 273 ## INTS:
 274 tinyint SMALLINT
 275 int INTEGER SERIAL
 276 bigint BIGINT
 277 real NUMERIC
 278 float NUMERIC
 279
 280 ## TEXT:
 281 varchar(15) TEXT
 282 varchar(32) TEXT
 283 varchar(70) TEXT
 284 varchar(255) TEXT
 285 varchar TEXT
 286 text TEXT
 287 tinytext TEXT
 288 ENUM TEXT
 289
 290 ## TIMESTAMPS:
 291 varbinary(14) TIMESTAMPTZ
 292 binary(14) TIMESTAMPTZ
 293 datetime TIMESTAMPTZ
 294 timestamp TIMESTAMPTZ
 295
 296 ## BYTEA:
 297 mediumblob BYTEA
 298
 299 ## OTHER:
 300 bool SMALLINT # Sigh
 301
 302 };
 303 ## Allow specific exceptions to the above
 304 my $COLMAPOK = q{
 305 ## User inputted text strings:
 306 ar_comment      tinyblob       TEXT
 307 fa_description  tinyblob       TEXT
 308 img_description tinyblob       TEXT
 309 ipb_reason      tinyblob       TEXT
 310 log_action      varbinary(32)  TEXT
 311 log_type        varbinary(32)  TEXT
 312 oi_description  tinyblob       TEXT
 313 rev_comment     tinyblob       TEXT
 314 rc_log_action   varbinary(255) TEXT
 315 rc_log_type     varbinary(255) TEXT
 316
 317 ## Simple text-only strings:
 318 ar_flags          tinyblob       TEXT
 319 ct_params         blob           TEXT
 320 fa_minor_mime     varbinary(100) TEXT
 321 fa_storage_group  varbinary(16)  TEXT # Just 'deleted' for now, should stay plain text
 322 fa_storage_key    varbinary(64)  TEXT # sha1 plus text extension
 323 ipb_address       tinyblob       TEXT # IP address or username
 324 ipb_range_end     tinyblob       TEXT # hexadecimal
 325 ipb_range_start   tinyblob       TEXT # hexadecimal
 326 img_minor_mime    varbinary(100) TEXT
 327 lc_lang           varbinary(32)  TEXT
 328 lc_value          varbinary(32)  TEXT
 329
 330 img_sha1          varbinary(32)  TEXT
 331 job_cmd           varbinary(60)  TEXT # Should we limit to 60 as well?
 332 keyname           varbinary(255) TEXT # No tablename prefix (objectcache)
 333 ll_lang           varbinary(20)  TEXT # Language code
 334 lc_value          mediumblob     TEXT
 335 log_params        blob           TEXT # LF separated list of args
 336 log_type          varbinary(10)  TEXT
 337 ls_field          varbinary(32)  TEXT
 338 oi_minor_mime     varbinary(100) TEXT
 339 oi_sha1           varbinary(32)  TEXT
 340 old_flags         tinyblob       TEXT
 341 old_text          mediumblob     TEXT
 342 pp_propname       varbinary(60)  TEXT
 343 pp_value          blob           TEXT
 344 page_restrictions tinyblob       TEXT # CSV string
 345 pf_server         varchar(30)    TEXT
 346 pr_level          varbinary(60)  TEXT
 347 pr_type           varbinary(60)  TEXT
 348 pt_create_perm    varbinary(60)  TEXT
 349 pt_reason         tinyblob       TEXT
 350 qc_type           varbinary(32)  TEXT
 351 qcc_type          varbinary(32)  TEXT
 352 qci_type          varbinary(32)  TEXT
 353 rc_params         blob           TEXT
 354 rlc_to_blob       blob           TEXT
 355 ts_tags           blob           TEXT
 356 ug_group          varbinary(16)  TEXT
 357 ul_value          blob           TEXT
 358 up_property       varbinary(32)  TEXT
 359 up_value          blob           TEXT
 360 user_email_token  binary(32)     TEXT
 361 user_ip           varbinary(40)  TEXT
 362 user_newpassword  tinyblob       TEXT
 363 user_options      blob           TEXT
 364 user_password     tinyblob       TEXT
 365 user_token        binary(32)     TEXT
 366 iwl_prefix      varbinary(20)  TEXT
 367
 368 ## Text URLs:
 369 el_index blob           TEXT
 370 el_to    blob           TEXT
 371 iw_url   blob           TEXT
 372 tb_url   blob           TEXT
 373 tc_url   varbinary(255) TEXT
 374
 375 ## Deprecated or not yet used:
 376 ar_text     mediumblob TEXT
 377 job_params  blob       TEXT
 378 log_deleted tinyint    INTEGER # Not used yet, but keep it INTEGER for safety
 379 rc_type     tinyint    CHAR
 380
 381 ## Number tweaking:
 382 fa_bits   int SMALLINT # bits per pixel
 383 fa_height int SMALLINT
 384 fa_width  int SMALLINT # Hope we don't see an image this wide...
 385 hc_id     int BIGINT   # Odd that site_stats is all bigint...
 386 img_bits  int SMALLINT # bits per image should stay sane
 387 oi_bits   int SMALLINT
 388
 389 ## True binary fields, usually due to gzdeflate and/or serialize:
 390 math_inputhash  varbinary(16) BYTEA
 391 math_outputhash varbinary(16) BYTEA
 392
 393 ## Namespaces: not need for such a high range
 394 ar_namespace     int SMALLINT
 395 job_namespace    int SMALLINT
 396 log_namespace    int SMALLINT
 397 page_namespace   int SMALLINT
 398 pl_namespace     int SMALLINT
 399 pt_namespace     int SMALLINT
 400 qc_namespace     int SMALLINT
 401 rc_namespace     int SMALLINT
 402 rd_namespace     int SMALLINT
 403 rlc_to_namespace int SMALLINT
 404 tl_namespace     int SMALLINT
 405 wl_namespace     int SMALLINT
 406
 407 ## Easy enough to change if a wiki ever does grow this big:
 408 ss_active_users  bigint INTEGER
 409 ss_good_articles bigint INTEGER
 410 ss_total_edits   bigint INTEGER
 411 ss_total_pages   bigint INTEGER
 412 ss_total_views   bigint INTEGER
 413 ss_users         bigint INTEGER
 414
 415 ## True IP - keep an eye on these, coders tend to make textual assumptions
 416 rc_ip varbinary(40) CIDR # Want to keep an eye on this
 417
 418 ## Others:
 419 tc_time int TIMESTAMPTZ
 420
 421
 422 };
 423
 424 my %colmap;
 425 for (split /\n/ => $COLMAP) {
 426         next unless /^\w/;
 427         s/(.*?)#.*/$1/;
 428         my ($col,@maps) = split / +/, $_;
 429         for (@maps) {
 430                 $colmap{$col}{$_} = 1;
 431         }
 432 }
 433
 434 my %colmapok;
 435 for (split /\n/ => $COLMAPOK) {
 436         next unless /^\w/;
 437         my ($col,$old,$new) = split / +/, $_;
 438         $colmapok{$col}{$old}{$new} = 1;
 439 }
 440
 441 ## Old but not new
 442 for my $t (sort keys %{$old{$oldfile}}) {
 443         if (!exists $new{$t} and !exists $ok{OLD}{$t}) {
 444                 print "Table not in $new: $t\n";
 445                 next;
 446         }
 447         next if exists $ok{OLD}{$t} and !$ok{OLD}{$t};
 448         my $newt = exists $ok{OLD}{$t} ? $ok{OLD}{$t} : $t;
 449         my $oldcol = $old{$oldfile}{$t}{column};
 450         my $oldcolfull = $old{$oldfile}{$t}{columnfull};
 451         my $newcol = $new{$newt}{column};
 452         for my $c (keys %$oldcol) {
 453                 if (!exists $newcol->{$c}) {
 454                         print "Column $t.$c not in $new\n";
 455                         next;
 456                 }
 457         }
 458         for my $c (sort keys %$newcol) {
 459                 if (!exists $oldcol->{$c}) {
 460                         print "Column $t.$c not in $oldfile\n";
 461                         next;
 462                 }
 463                 ## Column types (roughly) match up?
 464                 my $new = $newcol->{$c};
 465                 my $old = $oldcolfull->{$c};
 466
 467                 ## Known exceptions:
 468                 next if exists $colmapok{$c}{$old}{$new};
 469
 470                 $old =~ s/ENUM.*/ENUM/;
 471                 if (! exists $colmap{$old}{$new}) {
 472                         print "Column types for $t.$c do not match: $old does not map to $new\n";
 473                 }
 474         }
 475 }
 476 ## New but not old:
 477 for (sort keys %new) {
 478         if (!exists $old{$oldfile}{$_} and !exists $ok{NEW}{$_}) {
 479                 print "Not in $oldfile: $_\n";
 480                 next;
 481         }
 482 }
 483
 484
 485 } ## end each file to be parsed
 486
 487
 488 sub check_valid_sql {
 489
 490         ## Check for a few common problems in most php files
 491
 492         my $olddir = getcwd();
 493         chdir("../..");
 494         for my $basedir (qw/includes extensions/) {
 495                 scan_dir($basedir);
 496         }
 497         chdir $olddir;
 498
 499         return;
 500
 501 } ## end of check_valid_sql
 502
 503
 504 sub scan_dir {
 505
 506         my $dir = shift;
 507
 508         opendir my $dh, $dir or die qq{Could not opendir $dir: $!\n};
 509         #print "Scanning $dir...\n";
 510         for my $file (grep { -f "$dir/$_" and /\.php$/ } readdir $dh) {
 511                 find_problems("$dir/$file");
 512         }
 513         rewinddir $dh;
 514         for my $subdir (grep { -d "$dir/$_" and ! /\./ } readdir $dh) {
 515                 scan_dir("$dir/$subdir");
 516         }
 517         closedir $dh or die qq{Closedir failed: $!\n};
 518         return;
 519
 520 } ## end of scan_dir
 521
 522 sub find_problems {
 523
 524         my $file = shift;
 525         open my $fh, '<', $file or die qq{Could not open "$file": $!\n};
 526         my $lastline = '';
 527         my $inarray = 0;
 528         while (<$fh>) {
 529                 if (/FORCE INDEX/ and $file !~ /Database\w*\.php/) {
 530                         warn "Found FORCE INDEX string at line $. of $file\n";
 531                 }
 532                 if (/REPLACE INTO/ and $file !~ /Database\w*\.php/) {
 533                         warn "Found REPLACE INTO string at line $. of $file\n";
 534                 }
 535                 if (/\bIF\s*\(/ and $file !~ /DatabaseMySQL\.php/) {
 536                         warn "Found IF string at line $. of $file\n";
 537                 }
 538                 if (/\bCONCAT\b/ and $file !~ /Database\w*\.php/) {
 539                         warn "Found CONCAT string at line $. of $file\n";
 540                 }
 541                 if (/\bGROUP\s+BY\s*\d\b/i and $file !~ /Database\w*\.php/) {
 542                         warn "Found GROUP BY # at line $. of $file\n";
 543                 }
 544                 if (/wfGetDB\s*\(\s+\)/io) {
 545                         warn "wfGETDB is missing parameters at line $. of $file\n";
 546                 }
 547                 if (/=\s*array\s*\(\s*$/) {
 548                         $inarray = 1;
 549                         next;
 550                 }
 551                 if ($inarray) {
 552                         if (/\s*\);\s*$/) {
 553                                 $inarray = 0;
 554                                 next;
 555                         }
 556                         next if ! /\w/ or /array\(\s*$/ or /^\s*#/ or m{^\s*//};
 557                         if (! /,/) {
 558                                 my $nextline = <$fh>;
 559                                 last if ! defined $nextline;
 560                                 if ($nextline =~ /^\s*\)[;,]/) {
 561                                         $inarray = 0;
 562                                         next;
 563                                 }
 564                                 #warn "Array is missing a comma? Line $. of $file\n";
 565                         }
 566                 }
 567         }
 568         close $fh or die qq{Could not close "$file": $!\n};
 569         return;
 570
 571 } ## end of find_problems
 572
 573
 574 __DATA__
 575 ## Known exceptions
 576 OLD: searchindex          ## We use tsearch2 directly on the page table instead
 577 RENAME: user mwuser       ## Reserved word causing lots of problems
 578 RENAME: text pagecontent  ## Reserved word
 579 XFILE: ../archives/patch-profiling.sql